久久久91-久久久91精品国产一区二区-久久久91精品国产一区二区三区-久久久999国产精品-久久久999久久久精品

      





    呂衛陽            

    男，工學博士，副教授，現就職于北京科技大學機械工程學院機械電子工程系，主要研究方向為工業控制及自動化和先進機電系統技術。


    摘  要：本文討論了有關控制系統的基本算法及軟件實現的若干問題。介紹了線性控制系統的8個典型環節，給出了這些典型環節的時間響應功能塊。介紹了PID控制的基本原理及離散算法，給出了能夠實現PID基本算法的功能塊BasicPID，并舉例說明。

    關鍵詞：典型環節；PID算法；軟件實現

    Abstract: Some topics on the basic algorithm and software implementation of control system are discussed in this paper. The 8 essential blocks of the linear control system are introduced, and then give the function block of their time response. The basic theory and discrete method of PID control algorithm are introduced, and then give the function block BasicPID to implement the basic PID algorithm with some example.

    Key words: Essential Block; PID Algorithm; Software Implementation

    1 控制系統典型環節的時間響應

    控制系統一般由若干元件以一定的形式連接而成，這些元件的物理結構和工作原理可以是多種多樣的。但是從控制理論來看，物理本質和工作原理不同的元件，可以有完全相同的數學模型，亦即具有相同的動態特性。在控制工程中，常常將具有某種確定信息傳遞關系的元件、元件組或元件的一部分稱為一個環節，經常遇到的環節則稱為典型環節。這樣，任何復雜的系統總可以歸結為由一些典型的環節組成，從而為建立系統模型和研究系統特性帶來方便，使問題簡化。

    在一般情況下，線性控制系統都可以由比例環節、積分環節、微分環節、一階慣性環節、二階振蕩環節、一階微分環節、二階微分環節和延遲環節等8個典型環節組成。下面分別研究這些典型環節所對應的微分方程的數值解，也即研究其時間響應的離散算法。

    以下分別給出這些典型環節的時間響應離散算法的迭代公式，采用工業自動化編程標準IEC61131-3支持的ST語言在功能塊中實現。

    1.1 比例環節

    比例環節的傳遞函數：

    所對應的微分方程：

    以采樣周期TS進行采樣，得離散化后的差分方程： 

    比例環節功能塊ProportionalBlock如圖1.1所示，其變量聲明和程序代碼如下所示。

                   

                   圖1.1   比例環節功能塊ProportionalBlock

FUNCTION_BLOCK ProportionalBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 K: REAL;(*比例環節的比例常數，無量綱*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*比例環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=K*IN;(*比例環節的迭代公式。*)
END_IF

1.2 積分環節

積分環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

積分環節功能塊IntegralBlock如圖1.2所示，其變量聲明和程序代碼如下所示。
 
              

                    圖1.2   積分環節功能塊IntegralBlock

FUNCTION_BLOCK IntegralBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 OUT1: REAL;(*前一個采樣周期的輸出值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*積分環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=OUT1+IN*TS;(*積分環節的迭代公式。*)
 OUT1:=OUT;(*輸出值替換。*)
END_IF


1.3 微分環節

微分環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

微分環節功能塊DifferentialBlock如圖1.3所示，其變量聲明和程序代碼如下所示。
 
             

                 圖1.3   微分環節功能塊DifferentialBlock

FUNCTION_BLOCK DifferentialBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
END_VAR

VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 IN1: REAL;(*前一個采樣周期的輸入值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*微分環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=(IN-IN1)/TS;(*微分環節的迭代公式。*)
 IN1:=IN;(*輸入值替換。*)
END_IF

1.4 一階慣性環節

一階慣性環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

一階慣性環節功能塊FirstOrderLagBlock如圖1.4所示，其變量聲明和程序代碼如下所示。

               

                   圖1.4   一階慣性環節功能塊FirstOrderLagBlock

FUNCTION_BLOCK FirstOrderLagBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 T: REAL;(*一階慣性環節的時間常數，秒*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 OUT1: REAL;(*前一個采樣周期的輸出值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*一階慣性環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=(TS*IN+T*OUT1)/(T+TS);(*一階慣性環節的迭代公式。*)
 OUT1:=OUT;(*輸出值替換。*)
END_IF

1.5 二階振蕩環節

二階振蕩環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：



二階振蕩環節功能塊SecondOrderLagBlock如圖1.5所示，其變量聲明和程序代碼如下所示。
 
          

           圖1.5   二階振蕩環節功能塊SecondOrderLagBlock

FUNCTION_BLOCK SecondOrderLagBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 T: REAL;(*二階振蕩環節的時間常數，秒*)
 Zeta: REAL;(*二階振蕩環節的阻尼比*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 OUT1: REAL;(*前一個采樣周期的輸出值*)
 OUT2: REAL;(*前兩個采樣周期的輸出值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*二階振蕩環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=(TS*TS*IN+2*T*(T+Zeta*TS)*OUT1-T*T*OUT2)/(T*T+2*Zeta*T*TS+TS*TS);(*二階振蕩環節的迭代公式。*)
 OUT2:=OUT1;(*輸出值替換。*)
 OUT1:=OUT;(*輸出值替換。*)
END_IF

1.6 一階微分環節

一階微分環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

一階微分環節功能塊FirstOrderLeadBlock如圖1.6所示，其變量聲明和程序代碼如下所示。

            

               圖1.6   一階微分環節功能塊FirstOrderLeadBlock

FUNCTION_BLOCK FirstOrderLeadBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 T: REAL;(*一階微分環節的時間常數，秒*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 IN1: REAL;(*前一個采樣周期的輸入值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*一階微分環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=(IN-IN1)*T/TS+IN;(*一階微分環節的迭代公式。*)
 IN1:=IN;(*輸入值替換。*)
END_IF

1.7 二階微分環節

二階微分環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

二階微分環節功能塊SecondOrderLeadBlock如圖1.7所示，其變量聲明和程序代碼如下所示。
 
            

              圖1.7   二階微分環節功能塊SecondOrderLeadBlock

FUNCTION_BLOCK SecondOrderLeadBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 T: REAL;(*二階微分環節的時間常數，秒*)
 Zeta: REAL;(*二階微分環節的阻尼比*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 IN1: REAL;(*前一個采樣周期的輸入值*)
 IN2: REAL;(*前兩個采樣周期的輸入值*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*二階微分環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 OUT:=(IN-2*IN1+IN2)*T*T/TS/TS+(IN-IN1)*2*Zeta*T/TS+IN;(*二階微分環節的迭代公式。*)
 IN2:=IN1;(*輸入值替換。*)
 IN1:=IN;(*輸入值替換。*)
END_IF

1.8 延遲環節

延遲環節的傳遞函數：

所對應的微分方程：

以采樣周期TS進行采樣，得離散化后的差分方程：

延遲環節功能塊DelayBlock如圖1.8所示，其變量聲明和程序代碼如下所示。

           

                       圖1.8 延遲環節功能塊DelayBlock

FUNCTION_BLOCK DelayBlock
VAR_INPUT
 IN: REAL;(*輸入值*)
 TS: REAL;(*采樣周期，秒*)
 Delay: TIME;(*延遲的時間，秒*)
END_VAR
VAR_OUTPUT
 OUT: REAL;(*輸出值*)
END_VAR
VAR
 TimePeriod: TP;(*定時器*)
 RisingTrigger: R_TRIG;(*觸發器*)
 TONDelay: TON;(*定時器*)
END_VAR
(*采樣周期的判斷。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*延遲環節的時間響應。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 TONDelay(IN := TRUE, PT := Delay);(*調用定時器。*)
 IF TONDelay.Q THEN(*如果到達延遲的時間，則開始輸出。*)
  OUT := IN;
 END_IF
END_IF

2 PID控制的基本原理及離散算法

2.1 PID控制的基本概念

PID控制是控制工程中技術成熟且應用廣泛的一種控制策略。經過長期的工程實踐，已經形成了一套完整的PID控制方法和典型結構，不僅適用于數學模型已知的控制系統，而且對于數學模型難以確定的工業過程也可以應用。PID控制參數整定方便，結構改變靈活，在眾多工業過程控制中取得了滿意的應用效果。

在閉環負反饋控制系統中，系統的偏差信號e(t)是系統進行控制的最基本的原始信號。為了提高控制系統的性能指標，可以對偏差信號e(t)進行改造，使其按照某種函數關系進行變化，形成所需要的控制規律u(t)，從而使控制系統達到所要求的性能指標，即 
 
所謂PID控制，就是對偏差信號e(t)進行“比例加積分加微分”形式的改造，形成新的控制規律u(t)。即
 

 
其中：

 是比例控制部分， 稱為比例常數；

 是積分控制部分， 稱為積分時間常數；

 是微分控制部分， 稱為微分時間常數。

在零初始條件下，將上式兩邊取拉普拉斯變換，可得


 
基于PID控制的閉環負反饋控制系統的傳遞函數方塊圖如圖2.1所示。
 
                   圖2.1   基于PID控制的閉環負反饋控制系統

2.2 PID控制的離散算法

（1）位置式算法

設采樣周期為T，將前述PID控制規律u(t)進行離散化處理，可得PID控制的第k個采樣周期的位置式離散算法u(k)為


 
其中：

比例控制部分  離散化為 。

積分控制部分 離散化為 。令，并稱為積分控制部分的加權系數。

微分控制部分 離散化為。令 ，并稱為微分控制部分的加權系數。

（2）增量式算法

根據PID控制的位置式離散算法，可得PID控制的第k-1個采樣周期的位置式輸出為


 
將上述兩式u(k)與u(k-1)相減，可得PID控制的第k個采樣周期的增量式離散算法 為

于是可得PID控制的第k個采樣周期的位置式輸出u(k)為

2.3 PID控制的程序實現

功能塊BasicPID如圖2.2所示。

在功能塊BasicPID中，采用ST語言實現了PID控制的基本離散算法，其變量聲明和程序代碼如下所示，可以同時提供位置式輸出和增量式輸出。
 

                        

               圖2.2   PID控制的基本離散算法功能塊BasicPID

FUNCTION_BLOCK BasicPID
VAR_INPUT
 SP: REAL; (* Setpoint/設定點 *)
 PV: REAL; (* Process Variable/過程值，或稱Input/輸入值，或稱Feedback/反饋值 *)
 TS: REAL := 1; (* Sample Time/采樣間隔，或稱Loop Update Time/計算周期，秒 *)
 KP: REAL := 1; (* ISA Dependent Gains/ISA相關增益，無量綱 *)
 TI: REAL := 1; (* Integral Time/積分時間常數>0，秒 *)
 TD: REAL := 0; (* Differential Time/微分時間常數>=0，秒 *)
END_VAR
VAR_OUTPUT
 CV: REAL; (* Control Variable from the Current Sampling Step/當前采樣周期的位置式輸出值 *)
 dCV: REAL; (* Delta CV or CV Change from the Current Sampling Step/當前采樣周期的增量式輸出值 *)
END_VAR
VAR
 TimePeriod: TP; (* 定時器 *)
 RisingTrigger: R_TRIG; (* 觸發器 *)
 ki: REAL; (* Integral Gain/積分增益系數 *)
 kd: REAL; (* Differential Gain/微分增益系數 *)
 ev0: REAL; (* Error Variable or System Deviation from the Current Sampling Step/當前采樣周期的偏差值ev(k)=SP(k)-PV(k) *)
 ev1: REAL; (* Error Variable or System Deviation from the Previous Sampling Step/前一個采樣周期的偏差值ev(k-1)=SP(k-1)-PV(k-1) *)

 ev2: REAL; (* Error Variable or System Deviation from the Previous before Previous Sampling Step/前兩個采樣周期的偏差值ev(k-2)=SP(k-2)-PV(k-2) *)
 cv1: REAL; (* Control Variable from the Previous Sampling Step/前一個采樣周期的位置式輸出值 *)
END_VAR
(*參數的判斷與計算。*)
IF NOT(TS>0) THEN(*采樣周期必須大于0，否則將其置為1秒。*)
 TS:=1;
END_IF
IF NOT(TI>0) THEN(*積分時間常數必須大于0，否則將其置為0，表示沒有積分環節，但是應當避免被0除。*)
 TI:=0;(*如果積分時間常數為負或為0，則將其置為0，表示沒有積分環節。*)
 ki:=0;(*此時將積分增益系數置為0，表示沒有積分環節。*)
ELSE
 ki:=KP/TI*TS;(*計算積分增益系數，無量綱/秒*秒=無量綱，即離散化后此系數無量綱。*)
END_IF
IF TD<0 THEN(*可以沒有微積分環節，但是微分時間常數不能為負。*)
 TD:=0;(*如果微分時間常數為負，則將其置為0，表示沒有微分環節。*)
 kd:=0;(*此時將微分增益系數置為0，表示沒有微分環節。*)
ELSE
 kd:=KP*TD/TS;(*計算微分增益系數，無量綱*秒/秒=無量綱，即離散化后此系數無量綱。*)
END_IF
(*采樣周期的生成。*)
TimePeriod(IN:=NOT(TimePeriod.Q),PT:=REAL_TO_TIME(TS*1000));(*調用定時器。*)
RisingTrigger(CLK:=TimePeriod.Q);(*調用觸發器。*)
(*PID算法的迭代過程。*)
IF RisingTrigger.Q THEN(*在采樣時刻進行迭代計算。*)
 ev0:=SP-PV;(*計算偏差值。*)
 dCV:=KP*(ev0-ev1)+ki*ev0+kd*(ev0-2*ev1+ev2);(*當前采樣周期的增量式輸出值的迭代公式。*)
 CV:=cv1+dCV;(*當前采樣周期的位置式輸出值的迭代公式。*)
 ev2:=ev1;(*偏差值迭代。*)
 ev1:=ev0;(*偏差值迭代。*)
 cv1:=CV;(*位置式輸出值迭代。*)
END_IF

3 算法舉例

【例1】某單位負反饋控制系統如圖3.1所示，其開環傳遞函數為。試在PLC中編程計算其單位階躍響應。
 

              

                 圖3.1   單位負反饋控制系統

【解】首先將該系統的開環傳遞函數分解為典型環節的組合：


 
因此，該系統的開環傳遞函數由比例環節、積分環節和一階慣性環節的串聯所組成，其結構分解圖如圖3.2所示，在編程時可以分別調用上述典型環節所對應的功能塊。

              

                圖3.2   單位負反饋控制系統的結構分解圖

采用LD語言計算該系統的單位階躍響應，變量聲明如下：

PROGRAM PLC_PRG
VAR
 Ts1: REAL := 0.1; (* 采樣時間，秒 *)
 SP1: REAL := 1; (* 設定值 *)
 PV1: REAL; (* 過程值 *)
 ProportionalBlock1: ProportionalBlock; (* 比例環節 *)
 ProportionalBlock1OUT: REAL; (* 比例環節的輸出 *)
 IntegralBlock1: IntegralBlock; (* 積分環節 *)
 IntegralBlock1OUT: REAL; (* 積分環節的輸出 *)
 FirstOrderLagBlock1: FirstOrderLagBlock; (* 一階慣性環節 *)
 FirstOrderLagBlock1OUT: REAL; (* 一階慣性環節的輸出 *)
END_VAR

LD如圖3.3所示，單位階躍響應曲線如圖3.4所示。

                 

                      圖3.3   采用LD計算單位階躍響應

           

                     圖3.4   單位階躍響應曲線

【例2】帶有PID控制器的單位負反饋控制系統如圖3.5所示，已知 。試在PLC中編程計算其單位階躍響應。
            

                 圖3.5   帶有PID控制器的單位負反饋控制系統

【解】本例與例1所述的系統基本相同，唯一不同之處是增加了PID控制器。采用CFC語言計算該系統的單位階躍響應，變量聲明如下：

PROGRAM PLC_PRG
VAR
 Ts1: REAL := 0.1; (* 采樣時間，秒 *)
 SP1: REAL := 1; (* 設定值 *)
 PV1: REAL; (* 過程值 *)
 BasicPID1: BasicPID; (* PID控制器 *)
 KP1: REAL := 2; (* PID控制器的相關增益常數，無量綱 *)
 TI1: REAL := 3; (* PID控制器的積分時間常數，秒 *)
 TD1: REAL := 1; (* PID控制器的微分時間常數，秒 *)
 ProportionalBlock1: ProportionalBlock; (* 比例環節 *)
 IntegralBlock1: IntegralBlock; (* 積分環節 *)
 FirstOrderLagBlock1: FirstOrderLagBlock; (* 一階慣性環節 *)
END_VAR

             

                  圖3.6   采用CFC計算帶有PID控制器的單位階躍響應

               

                   圖3.7   帶有PID控制器的單位階躍響應曲線

CFC如圖3.6所示，單位階躍響應曲線如圖3.7所示。比較圖3.4和圖3.7可以看出，采用PID控制后，改善了系統的綜合性能。


                                                      ——轉自《自動化博覽》